# ParticleSizeApp.pro

QT       += core gui network serialport

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++14

# 项目名称
TARGET = ParticleSizeApp

# 模板类型
TEMPLATE = app

# 定义宏
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += UNICODE
DEFINES += _UNICODE

# 编码设置
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

INCLUDEPATH += $$PWD/Presenter/Inc

INCLUDEPATH += $$PWD/../../../VrCommon/Inc
INCLUDEPATH += $$PWD/../../../VrUtils/Inc
INCLUDEPATH += $$PWD/../../../VrNets/TCPServer/Inc

INCLUDEPATH += $$PWD/../../../Module/ShareMem/Inc

INCLUDEPATH += $$PWD/../ParticleSizeConfig/Inc
INCLUDEPATH += $$PWD/../../../VrEyeDevice/Inc


INCLUDEPATH += $$PWD/../../../AppUtils/CloudUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/UICommon/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppCommon/Inc

# 源文件
SOURCES += \
    Presenter/Src/ParticleSizePresenter.cpp \
    Presenter/Src/DetectPresenter.cpp \
    Presenter/Src/TCPServerProtocol.cpp \
    Presenter/Src/TCPServerMethods.cpp \
    main.cpp \
    mainwindow.cpp \
    dialogalgoarg.cpp \
    resultitem.cpp

# 头文件
HEADERS += \
    Presenter/Inc/ParticleSizePresenter.h \
    Presenter/Inc/DetectPresenter.h \
    Presenter/Inc/TCPServerProtocol.h \
    IYParticleSizeStatus.h \
    mainwindow.h \
    dialogalgoarg.h \
    resultitem.h \
    Version.h

# UI文件
FORMS += \
    mainwindow.ui \
    dialogalgoarg.ui \
    resultitem.ui

# 资源文件
RESOURCES += \
    resources.qrc \
    ../../../AppUtils/UICommon/common_resources.qrc

# Windows任务栏图标配置
win32 {
    RC_ICONS = resource/logo.ico
}

win32:CONFIG(debug, debug|release) {
    LIBS += -L../../../VrUtils/debug                -lVrUtils
    LIBS += -L../../../AppUtils/CloudUtils/debug   -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/debug      -lUICommon
    LIBS += -L../../../AppUtils/AppCommon/debug    -lAppCommon
    LIBS += -L../ParticleSizeConfig/debug              -lParticleSizeConfig
    LIBS += -L../../../VrEyeDevice/debug            -lVrEyeDevice
    LIBS += -L../../../Module/ModbusTCPServer/debug -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/debug        -lShareMem
    LIBS += -L../../../VrNets/debug                 -lVrModbus
    LIBS += -L../../../VrNets/debug                 -lVrTcpServer

}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../../VrUtils/release              -lVrUtils
    LIBS += -L../../../AppUtils/CloudUtils/release  -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/release     -lUICommon
    LIBS += -L../../../AppUtils/AppCommon/release   -lAppCommon
    LIBS += -L../ParticleSizeConfig/release            -lParticleSizeConfig
    LIBS += -L../../../VrEyeDevice/release          -lVrEyeDevice
    LIBS += -L../../../Module/ModbusTCPServer/release -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/release      -lShareMem
    LIBS += -L../../../VrNets/release               -lVrModbus
    LIBS += -L../../../VrNets/release               -lVrTcpServer
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    # 注意链接顺序：依赖关系从高到低（被依赖的库放在后面）
    LIBS += -L../ParticleSizeConfig              -lParticleSizeConfig
    LIBS += -L../../../AppUtils/UICommon       -lUICommon
    LIBS += -L../../../AppUtils/AppCommon     -lAppCommon
    LIBS += -L../../../AppUtils/CloudUtils    -lCloudUtils
    LIBS += -L../../../VrEyeDevice            -lVrEyeDevice
    LIBS += -L../../../Module/ModbusTCPServer -lModbusTCPServer
    LIBS += -L../../../VrNets                 -lVrModbus
    LIBS += -L../../../VrNets                 -lVrTcpServer
    LIBS += -L../../../Module/ShareMem        -lShareMem
    LIBS += -L../../../VrUtils                -lVrUtils

    # 添加系统库依赖
    LIBS += -lpthread
}

#linux下的为unix ，windows下用的win32

INCLUDEPATH += ../../../SDK/VzNLSDK/_Inc
INCLUDEPATH += ../../../SDK/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}


# 算法
INCLUDEPATH += ../../../SDK/particleSizeMeasure/Inc
INCLUDEPATH += ../../../SDK/Opencv320/include

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/particleSizeMeasure/Windows/x64/Release -lparticleSizeMeasurement -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/particleSizeMeasure/Windows/x64/Debug -lparticleSizeMeasurement -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Debug -lopencv_world320d
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/particleSizeMeasure/Arm/aarch64 -lparticleSizeMeasurement -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui -lopencv_imgcodecs
}

# 添加libmodbus依赖
win32 {
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}

# Default rules for deployment.
unix {
    target.path = /usr/lib
    # Link real-time library for POSIX shared memory functions
    LIBS += -lrt
}
!isEmpty(target.path): INSTALLS += target