QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TEMPLATE = app

# Add /utf-8 flag only for MSVC builds to enforce UTF-8 encoding
win32-msvc {
    CONFIG += c++11
    QMAKE_CXXFLAGS += /utf-8
}else{
    CONFIG += c++17
}

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0


# 设置应用程序图标
RC_ICONS = resource/logo.ico
INCLUDEPATH += $$PWD/Presenter/Inc
INCLUDEPATH += $$PWD/Utils/Inc

INCLUDEPATH += $$PWD/../../../VrCommon/Inc
INCLUDEPATH += $$PWD/../../../VrUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppCommon/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/UICommon/Inc

INCLUDEPATH += $$PWD/../../../VrNets/TCPServer/Inc
INCLUDEPATH += $$PWD/../../../Module/ShareMem/Inc

INCLUDEPATH += $$PWD/../LapWeldConfig/Inc
INCLUDEPATH += $$PWD/../../../VrEyeDevice/Inc

INCLUDEPATH += $$PWD/../../../AppUtils/CloudUtils/Inc

SOURCES += \
    Presenter/Src/DetectPresenter.cpp \
    Presenter/Src/LapWeldPresenter.cpp \
    Presenter/Src/TCPServerProtocol.cpp \
    devstatus.cpp \
    dialogalgoarg.cpp \
    main.cpp \
    mainwindow.cpp \
    resultitem.cpp

HEADERS += \
    Presenter/Inc/DetectPresenter.h \
    Presenter/Inc/LapWeldPresenter.h \
    Presenter/Inc/ProtocolCommon.h \
    Presenter/Inc/TCPServerProtocol.h \
    IYLapWeldStatus.h \
    Version.h \
    devstatus.h \
    dialogalgoarg.h \
    mainwindow.h \
    resultitem.h

FORMS += \
    devstatus.ui \
    dialogalgoarg.ui \
    mainwindow.ui \
    resultitem.ui

RESOURCES += \
    resources.qrc   \
    ../../../AppUtils/UICommon/common_resources.qrc


win32:CONFIG(debug, debug|release) {
    LIBS += -L../../../VrUtils/debug                -lVrUtils
    LIBS += -L../../../AppUtils/AppCommon/debug     -lAppCommon
    LIBS += -L../../../AppUtils/CloudUtils/debug    -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/debug       -lUICommon
    LIBS += -L../LapWeldConfig/debug                -lLapWeldConfig
    LIBS += -L../../../VrEyeDevice/debug            -lVrEyeDevice
    LIBS += -L../../../VrNets/debug                 -lVrTcpServer
    LIBS += -L../../../Module/ShareMem/debug        -lShareMem
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../../VrUtils/release              -lVrUtils
    LIBS += -L../../../AppUtils/AppCommon/release   -lAppCommon
    LIBS += -L../../../AppUtils/CloudUtils/release  -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/release     -lUICommon
    LIBS += -L../LapWeldConfig/release              -lLapWeldConfig
    LIBS += -L../../../VrEyeDevice/release          -lVrEyeDevice
    LIBS += -L../../../VrNets/release               -lVrTcpServer
    LIBS += -L../../../Module/ShareMem/release      -lShareMem
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    # 注意链接顺序：依赖关系从高到低
    LIBS += -L../LapWeldConfig                -lLapWeldConfig
    LIBS += -L../../../AppUtils/UICommon       -lUICommon
    LIBS += -L../../../AppUtils/AppCommon     -lAppCommon
    LIBS += -L../../../AppUtils/CloudUtils    -lCloudUtils
    LIBS += -L../../../VrEyeDevice            -lVrEyeDevice
    LIBS += -L../../../VrNets                 -lVrTcpServer
    LIBS += -L../../../Module/ShareMem        -lShareMem
    LIBS += -L../../../VrUtils                -lVrUtils

    # 添加系统库依赖
    LIBS += -lpthread
}

#linux下的为unix ，windows下用的win32

INCLUDEPATH += ../../../SDK/VzNLSDK/_Inc
INCLUDEPATH += ../../../SDK/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}


# 算法
INCLUDEPATH += ../../../SDK/lapWeldDetection/Inc
INCLUDEPATH += ../../../SDK/OpenCV320/include

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/lapWeldDetection/Windows/x64/Release -llapWeldDetection
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/lapWeldDetection/Windows/x64/Debug -llapWeldDetection
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/lapWeldDetection/Arm/aarch64 -llapWeldDetection -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui
}

# 添加libmodbus依赖
win32 {
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}

# Default rules for deployment.
unix {
    target.path = /usr/lib
    # Link real-time library for POSIX shared memory functions
    LIBS += -lrt
}
!isEmpty(target.path): INSTALLS += target


# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target