QT       += core gui
QT       += serialport

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TEMPLATE = app

CONFIG += c++17
# Add /utf-8 flag only for MSVC builds to enforce UTF-8 encoding
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}


# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

# 设置应用程序图标
RC_ICONS = resource/logo.ico

INCLUDEPATH += $$PWD/../VrCommon/Inc
INCLUDEPATH += $$PWD/../VrUtils/Inc
INCLUDEPATH += $$PWD/Presenter/Inc
INCLUDEPATH += $$PWD/Utils/Inc

INCLUDEPATH += $$PWD/../Module/ModbusTCPServer/Inc
INCLUDEPATH += $$PWD/../Module/ShareMem/Inc

INCLUDEPATH += $$PWD/../GrabBagConfig/Inc
INCLUDEPATH += $$PWD/../VrEyeDevice/Inc

SOURCES += \
    Presenter/Src/DetectPresenter.cpp \
    Presenter/Src/GrabBagPresenter.cpp \
    Presenter/Src/RobotProtocol.cpp \
    Presenter/Src/SerialProtocol.cpp \
    Presenter/Src/ConfigManager.cpp \
    Utils/Src/LaserDataLoader.cpp \
    Utils/Src/PathManager.cpp \
    Utils/Src/PointCloudImageUtils.cpp \
    devstatus.cpp \
    dialogcamera.cpp \
    dialogcameralevel.cpp \
    dialogconfig.cpp \
    main.cpp \
    mainwindow.cpp \
    resultitem.cpp

HEADERS += \
    Presenter/Inc/DetectPresenter.h \
    Presenter/Inc/GrabBagPresenter.h \
    Presenter/Inc/ProtocolCommon.h \
    Presenter/Inc/RobotProtocol.h \
    Presenter/Inc/SerialProtocol.h \
    Presenter/Inc/ConfigManager.h \
    Utils/Inc/LaserDataLoader.h \
    Utils/Inc/PathManager.h \
    IYGrabBagStatus.h \
    Utils/Inc/PointCloudImageUtils.h \
    Version.h \
    devstatus.h \
    dialogcamera.h \
    dialogcameralevel.h \
    dialogconfig.h \
    mainwindow.h \
    resultitem.h

FORMS += \
    devstatus.ui \
    dialogcamera.ui \
    dialogcameralevel.ui \
    dialogconfig.ui \
    mainwindow.ui \
    resultitem.ui

RESOURCES += \
    resources.qrc


win32:CONFIG(debug, debug|release) {
    LIBS += -L../VrUtils/debug          -lVrUtils
    LIBS += -L../GrabBagConfig/debug    -lGrabBagConfig
    LIBS += -L../VrEyeDevice/debug      -lVrEyeDevice
    LIBS += -L../Module/ModbusTCPServer/debug -lModbusTCPServer
    LIBS += -L../Module/ShareMem/debug  -lShareMem
    LIBS += -L../VrNets/debug           -lVrModbus
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../VrUtils/release        -lVrUtils
    LIBS += -L../GrabBagConfig/release  -lGrabBagConfig
    LIBS += -L../VrEyeDevice/release    -lVrEyeDevice
    LIBS += -L../Module/ModbusTCPServer/release -lModbusTCPServer
    LIBS += -L../Module/ShareMem/release -lShareMem
    LIBS += -L../VrNets/release         -lVrModbus
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    # 注意链接顺序：依赖关系从高到低
    LIBS += -L../GrabBagConfig          -lGrabBagConfig
    LIBS += -L../VrEyeDevice            -lVrEyeDevice
    LIBS += -L../Module/ModbusTCPServer -lModbusTCPServer
    LIBS += -L../VrNets                 -lVrModbus
    LIBS += -L../Module/ShareMem        -lShareMem
    LIBS += -L../VrUtils                -lVrUtils
    
    # 添加系统库依赖
    LIBS += -lpthread
}

#linux下的为unix ，windows下用的win32

INCLUDEPATH += ../SDK/VzNLSDK/_Inc
INCLUDEPATH += ../SDK/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../SDK/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../SDK/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../SDK/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}


# 算法
INCLUDEPATH += ../SDK/bagPosition/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../SDK/bagPosition/Windows/x64/Release -lbagPositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../SDK/bagPosition/Windows/x64/Debug -lbagPositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:unix:!macx: {
    LIBS += -L$$PWD/../SDK/bagPosition/Arm/aarch64 -lbagPositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui
}

# 添加libmodbus依赖
win32 {
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}

# Default rules for deployment.
unix {
    target.path = /usr/lib
    # Link real-time library for POSIX shared memory functions
    LIBS += -lrt
}
!isEmpty(target.path): INSTALLS += target


# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target