# WorkpieceApp.pro

QT       += core gui network serialport

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++17

# 项目名称
TARGET = WorkpieceApp

# 模板类型
TEMPLATE = app

# 定义宏
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += UNICODE
DEFINES += _UNICODE

# 编码设置
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

INCLUDEPATH += $$PWD/Presenter/Inc

INCLUDEPATH += $$PWD/../../../VrCommon/Inc
INCLUDEPATH += $$PWD/../../../VrUtils/Inc

INCLUDEPATH += $$PWD/../../../Module/ShareMem/Inc

INCLUDEPATH += $$PWD/../WorkpieceConfig/Inc
INCLUDEPATH += $$PWD/../../../VrEyeDevice/Inc

INCLUDEPATH += $$PWD/../../../VrNets/TCPServer/Inc

INCLUDEPATH += $$PWD/../../../AppUtils/CloudUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/UIUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppCommon/Inc

# 源文件
SOURCES += \
    Presenter/Src/WorkpiecePresenter.cpp \
    Presenter/Src/ConfigManager.cpp \
    Presenter/Src/DetectPresenter.cpp \
    Presenter/Src/TCPServerProtocol.cpp \
    Presenter/Src/TCPServerMethods.cpp \
    main.cpp \
    mainwindow.cpp \
    dialogalgoarg.cpp \
    dialogcamera.cpp \
    dialogcameralevel.cpp \
    devstatus.cpp \
    resultitem.cpp

# 头文件
HEADERS += \
    Presenter/Inc/WorkpiecePresenter.h \
    Presenter/Inc/ConfigManager.h \
    Presenter/Inc/DetectPresenter.h \
    Presenter/Inc/TCPServerProtocol.h \
    Presenter/Inc/ProtocolCommon.h \
    IYWorkpieceStatus.h \
    mainwindow.h \
    dialogalgoarg.h \
    dialogcamera.h \
    dialogcameralevel.h \
    devstatus.h \
    resultitem.h \
    Version.h

# UI文件
FORMS += \
    mainwindow.ui \
    dialogalgoarg.ui \
    dialogcamera.ui \
    dialogcameralevel.ui \
    devstatus.ui \
    resultitem.ui

# 资源文件
RESOURCES += \
    resources.qrc

# Windows任务栏图标配置
win32 {
    RC_ICONS = resource/logo.ico
}

win32:CONFIG(debug, debug|release) {
    LIBS += -L../../../VrUtils/debug                -lVrUtils
    LIBS += -L../../../AppUtils/CloudUtils/debug   -lCloudUtils
    LIBS += -L../../../AppUtils/UIUtils/debug      -lUIUtils
    LIBS += -L../../../AppUtils/AppCommon/debug    -lAppCommon
    LIBS += -L../WorkpieceConfig/debug              -lWorkpieceConfig
    LIBS += -L../../../VrEyeDevice/debug            -lVrEyeDevice
    LIBS += -L../../../Module/ModbusTCPServer/debug -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/debug        -lShareMem
    LIBS += -L../../../VrNets/debug                 -lVrModbus
    LIBS += -L../../../VrNets/debug                 -lVrTcpServer

}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../../VrUtils/release              -lVrUtils
    LIBS += -L../../../AppUtils/CloudUtils/release -lCloudUtils
    LIBS += -L../../../AppUtils/UIUtils/release    -lUIUtils
    LIBS += -L../../../AppUtils/AppCommon/release  -lAppCommon
    LIBS += -L../WorkpieceConfig/release            -lWorkpieceConfig
    LIBS += -L../../../VrEyeDevice/release          -lVrEyeDevice
    LIBS += -L../../../Module/ModbusTCPServer/release -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/release      -lShareMem
    LIBS += -L../../../VrNets/release               -lVrModbus
    LIBS += -L../../../VrNets/release               -lVrTcpServer
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    # 注意链接顺序：依赖关系从高到低
    LIBS += -L../WorkpieceConfig              -lWorkpieceConfig
    LIBS += -L../../../VrEyeDevice            -lVrEyeDevice
    LIBS += -L../../../Module/ModbusTCPServer -lModbusTCPServer
    LIBS += -L../../../VrNets                 -lVrModbus
    LIBS += -L../../../Module/ShareMem        -lShareMem
    LIBS += -L../../../VrNets                 -lVrTcpServer
    LIBS += -L../../../AppUtils/CloudUtils   -lCloudUtils
    LIBS += -L../../../AppUtils/UIUtils      -lUIUtils
    LIBS += -L../../../AppUtils/AppCommon    -lAppCommon
    LIBS += -L../../../VrUtils                -lVrUtils

    # 添加系统库依赖
    LIBS += -lpthread
}

#linux下的为unix ，windows下用的win32

INCLUDEPATH += ../../../SDK/VzNLSDK/_Inc
INCLUDEPATH += ../../../SDK/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}


# 算法
INCLUDEPATH += ../../../SDK/workpieceCornerExtraction/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/workpieceCornerExtraction/Windows/x64/Release -lBQ_workpieceCornerExtraction -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/workpieceCornerExtraction/Windows/x64/Debug -lBQ_workpieceCornerExtraction -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/workpieceCornerExtraction/Arm/aarch64 -lworkpieceCornerExtraction -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui
}

# 添加libmodbus依赖
win32 {
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}

# Default rules for deployment.
unix {
    target.path = /usr/lib
    # Link real-time library for POSIX shared memory functions
    LIBS += -lrt
}
!isEmpty(target.path): INSTALLS += target