GrabBag/App/BeltTearing/BeltTearingServer/BeltTearingServer.pro

QT       += core
QT       += network

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TEMPLATE = app

CONFIG += c++11 console
# Add /utf-8 flag only for MSVC builds to enforce UTF-8 encoding
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    # Define DLLBUILD for static libmodbus linking
    # This makes MODBUS_API expand to __declspec(dllexport) which works for static lib
    DEFINES += DLLBUILD
}

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

INCLUDEPATH += $$PWD/../../../VrCommon/Inc
INCLUDEPATH += $$PWD/../../../VrUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/CloudUtils/Inc
INCLUDEPATH += $$PWD/Presenter/Inc
INCLUDEPATH += $$PWD/Utils/Inc
INCLUDEPATH += $$PWD/../../../VrNets/modbus/Inc
INCLUDEPATH += $$PWD/../../../VrNets/TCPServer/Inc
INCLUDEPATH += $$PWD/../../../Module/ModbusTCPServer/Inc

INCLUDEPATH += $$PWD/../../../VrConfig/Inc
INCLUDEPATH += $$PWD/../../../VrEyeDevice/Inc
INCLUDEPATH += $$PWD/../BeltTearingConfig/Inc

# SDK算法库路径
INCLUDEPATH += $$PWD/../../../SDK/beltTearing/Inc

SOURCES += \
    main.cpp \
    BeltTearingPresenter.cpp \
    PointCloudImageUtils.cpp \
    PathManager.cpp \
    RobotProtocol.cpp \
    ModbusRTUMaster.cpp \
    TearingTcpProtocol.cpp

HEADERS += \
    BeltTearingPresenter.h \
    PointCloudImageUtils.h  \
    Version.h \
    RobotProtocol.h \
    ModbusRTUMaster.h \
    TearingTcpProtocol.h

FORMS +=

win32:CONFIG(debug, debug|release) {
    LIBS += -L../BeltTearingConfig/debug            -lBeltTearingConfig
    LIBS += -L../../../VrEyeDevice/debug            -lVrEyeDevice
    LIBS += -L../../../VrNets/debug                 -lVrTCPServer
    LIBS += -L../../../Module/ModbusTCPServer/debug -lModbusTCPServer
    LIBS += -L../../../VrNets/debug                 -lVrModbus
    LIBS += -L../../../VrUtils/debug                -lVrUtils
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../BeltTearingConfig/release              -lBeltTearingConfig
    LIBS += -L../../../VrEyeDevice/release              -lVrEyeDevice
    LIBS += -L../../../VrNets/release                   -lVrTCPServer
    LIBS += -L../../../Module/ModbusTCPServer/release   -lModbusTCPServer
    LIBS += -L../../../VrNets/release                   -lVrModbus
    LIBS += -L../../../VrUtils/release                  -lVrUtils
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    # 注意链接顺序：依赖关系从高到低
    LIBS += -L../BeltTearingConfig              -lBeltTearingConfig
    LIBS += -L../../../Module/ModbusTCPServer   -lModbusTCPServer
    LIBS += -L../../../VrNets                   -lVrModbus
    LIBS += -L../../../VrNets                   -lVrTCPServer
    LIBS += -L../../../VrEyeDevice              -lVrEyeDevice
    LIBS += -L../../../VrUtils                  -lVrUtils


    # 添加系统库依赖
    LIBS += -lpthread
}

#linux下的为unix ，windows下用的win32

INCLUDEPATH += ../../../SDK/VzNLSDK/_Inc
INCLUDEPATH += ../../../SDK/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}


# 算法
INCLUDEPATH += ../../../SDK/OpenCV320/include
win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320

    # SDK算法库
    LIBS += -L$$PWD/../../../SDK/beltTearing/Windows/x64/Release -lbeltTearingDetection
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
    # SDK算法库
    LIBS += -L$$PWD/../../../SDK/beltTearing/Windows/x64/Release -lbeltTearingDetection
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui

    # SDK算法库
    LIBS += -L$$PWD/../../../SDK/beltTearing/Arm/aarch64 -lbeltTearingDetection
}


# 添加Windows系统库依赖
win32 {
    LIBS += -lshell32
    LIBS += -lws2_32
    LIBS += -lAdvapi32
    
    # For serial communication on Windows
    LIBS += -lsetupapi
}