GrabBag/BeltTearingServer/BeltTearingServer.pro

QT       += core
QT       += network

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TEMPLATE = app

CONFIG += c++11 console
# Add /utf-8 flag only for MSVC builds to enforce UTF-8 encoding
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

INCLUDEPATH += $$PWD/../VrCommon/Inc
INCLUDEPATH += $$PWD/../VrUtils/Inc
INCLUDEPATH += $$PWD/Presenter/Inc
INCLUDEPATH += $$PWD/Utils/Inc

INCLUDEPATH += $$PWD/../VrConfig/Inc
INCLUDEPATH += $$PWD/../VrEyeDevice/Inc
INCLUDEPATH += $$PWD/../BeltTearingConfig/Inc

SOURCES += \
    BeltTearingAlgo.cpp     \
    beltTearingDetection.cpp \
    main.cpp \
    BeltTearingPresenter.cpp \
    PathManager.cpp

HEADERS += \
    SG_baseAlgo_Export.h \
    SG_baseDataType.h \
    SG_errCode.h \
    beltTearingDetection_Export.h   \
    BeltTearingAlgo.h \
    BeltTearingPresenter.h \
    PathManager.h \
    Version.h

FORMS +=

win32:CONFIG(debug, debug|release) {
    LIBS += -L../BeltTearingConfig/debug    -lBeltTearingConfig
    LIBS += -L../VrEyeDevice/debug          -lVrEyeDevice
    LIBS += -L../VrUtils/debug              -lVrUtils
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../BeltTearingConfig/release  -lBeltTearingConfig
    LIBS += -L../VrEyeDevice/release        -lVrEyeDevice
    LIBS += -L../VrUtils/release            -lVrUtils
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    # 注意链接顺序：依赖关系从高到低
    LIBS += -L../VrUtils                -lVrUtils
    LIBS += -L../BeltTearingConfig      -lBeltTearingConfig
    LIBS += -L../VrEyeDevice            -lVrEyeDevice
    
    # 添加系统库依赖
    LIBS += -lpthread
}

#linux下的为unix ，windows下用的win32

INCLUDEPATH += ../SDK/VzNLSDK/_Inc
INCLUDEPATH += ../SDK/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../SDK/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../SDK/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../SDK/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}


# 算法
INCLUDEPATH += ../SDK/OpenCV320/include
win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:unix:!macx: {
    LIBS += -L$$PWD/../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui
}


# 添加Windows系统库依赖
win32 {
    LIBS += -lshell32
    LIBS += -lws2_32
    LIBS += -lAdvapi32
}