GrabBag/GrabBagApp/GrabBagApp.pro

QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TEMPLATE = app

CONFIG += c++17

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

INCLUDEPATH += $$PWD/../VrCommon/Inc
INCLUDEPATH += $$PWD/../VrUtils/Inc
INCLUDEPATH += $$PWD/Presenter/Inc

INCLUDEPATH += $$PWD/../Module/ModbusTCPServer/Inc

INCLUDEPATH += $$PWD/../VrConfig/Inc
INCLUDEPATH += $$PWD/../VrEyeDevice/Inc

SOURCES += \
    Presenter/Src/GrabBagPresenter.cpp \
    Presenter/Src/LaserDataLoader.cpp \
    Presenter/Src/RobotProtocol.cpp \
    devstatus.cpp \
    dialogcamera.cpp \
    dialogconfig.cpp \
    main.cpp \
    mainwindow.cpp \
    resultitem.cpp

HEADERS += \
    Presenter/Inc/GrabBagPresenter.h \
    Presenter/Inc/LaserDataLoader.h \
    Presenter/Inc/RobotProtocol.h \
    IYGrabBagStatus.h \
    devstatus.h \
    dialogcamera.h \
    dialogconfig.h \
    mainwindow.h \
    resultitem.h

FORMS += \
    devstatus.ui \
    dialogcamera.ui \
    dialogconfig.ui \
    mainwindow.ui \
    resultitem.ui

RESOURCES += \
    resources.qrc


win32:CONFIG(debug, debug|release) {
    LIBS += -L../VrUtils/debug -lVrUtils
    LIBS += -L../VrConfig/debug -lVrConfig
    LIBS += -L../VrEyeDevice/debug -lVrEyeDevice
    LIBS += -L../Module/ModbusTCPServer/debug -lModbusTCPServer
    LIBS += -L../VrNets/debug -lVrNets
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../VrUtils/release -lVrUtils
    LIBS += -L../VrConfig/release -lVrConfig
    LIBS += -L../VrEyeDevice/release -lVrEyeDevice
    LIBS += -L../Module/ModbusTCPServer/release -lModbusTCPServer
    LIBS += -L../VrNets/release -lVrNets
}else:unix:!macx {
    # Unix/Linux平台库链接（包括交叉编译）
    # 注意链接顺序：依赖关系从高到低
    LIBS += -L../VrConfig       -lVrConfig  
    LIBS += -L../VrUtils        -lVrUtils
    LIBS += -L../VrEyeDevice    -lVrEyeDevice
    LIBS += -L../Module/ModbusTCPServer -lModbusTCPServer
    LIBS += -L../VrNets         -lVrNets
    
    # 添加系统库依赖
    LIBS += -lpthread
}

#linux下的为unix ，windows下用的win32

INCLUDEPATH += ../SDK/VzNLSDK/_Inc
INCLUDEPATH += ../SDK/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../SDK/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../SDK/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../SDK/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}


# 算法
INCLUDEPATH += ../SDK/bagPosition/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../SDK/bagPosition/Windows/x64/Release -lbagPositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../SDK/OpenCV480/Windows/x64/Release -lopencv_world480
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../SDK/bagPosition/Windows/x64/Debug -lbagPositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../SDK/OpenCV480/Windows/x64/Debug -lopencv_world480d
}
else:unix:!macx: {
    LIBS += -L$$PWD/../SDK/bagPosition/Arm/aarch64 -lbagPositioning -lbaseAlgorithm
}

# 添加libmodbus依赖
win32 {
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target